meta(flake.nix): Add overlays as outputs

Should make it easier for other repositories to use the overlays from
this repository.

flake.nix

@@ -37,5 +37,12 @@
       osu-backgrounds = callPackage ./packages/osu-backgrounds.nix { };
       webp-thumbnailer = callPackage ./packages/webp-thumbnailer.nix { };
     };
+
+    overlays = {
+      base16-schemes = import ./overlays/base16-schemes.nix;
+      kitty = import ./overlays/kitty.nix;
+      srb2 = import ./overlays/srb2.nix;
+      zola = import ./overlays/zola.nix;
+    };
   };
 }

overlays/base16-schemes.nix

@@ -1,25 +1,21 @@
-{
-  nixpkgs.overlays = [
-    (final: prev: {
-      base16-schemes = prev.base16-schemes.overrideAttrs (oldAttrs: {
-        version = "unstable-2023-05-02";
+(final: prev: {
+  base16-schemes = prev.base16-schemes.overrideAttrs (oldAttrs: {
+    version = "unstable-2023-05-02";
 
-        src = prev.fetchFromGitHub {
-          owner = "tinted-theming";
-          repo = "base16-schemes";
-          rev = "9a4002f78dd1094c123169da243680b2fda3fe69";
-          hash = "sha256-AngNF++RZQB0l4M8pRgcv66pAcIPY+cCwmUOd+RBJKA=";
-        };
+    src = prev.fetchFromGitHub {
+      owner = "tinted-theming";
+      repo = "base16-schemes";
+      rev = "9a4002f78dd1094c123169da243680b2fda3fe69";
+      hash = "sha256-AngNF++RZQB0l4M8pRgcv66pAcIPY+cCwmUOd+RBJKA=";
+    };
 
-        installPhase = ''
-          runHook preInstall
+    installPhase = ''
+      runHook preInstall
 
-          mkdir -p $out/share/themes/
-          install *.yaml $out/share/themes/
+      mkdir -p $out/share/themes/
+      install *.yaml $out/share/themes/
 
-          runHook postInstall
-        '';
-      });
-    })
-  ];
-}
+      runHook postInstall
+    '';
+  });
+})

overlays/default.nix

@@ -1,8 +1,8 @@
 {
-  imports = [
-    ./base16-schemes.nix
-    ./kitty.nix
-    ./srb2.nix
-    ./zola.nix
+  nixpkgs.overlays = [
+    (import ./base16-schemes.nix)
+    (import ./kitty.nix)
+    (import ./srb2.nix)
+    (import ./zola.nix)
   ];
 }

overlays/kitty.nix

@@ -1,26 +1,22 @@
-{
-  nixpkgs.overlays = [
-    (final: prev: {
-      kitty = prev.kitty.overrideAttrs (oldAttrs: rec {
-        version = "0.31.0";
+(final: prev: {
+  kitty = prev.kitty.overrideAttrs (oldAttrs: rec {
+    version = "0.31.0";
 
-        src = prev.fetchFromGitHub {
-          owner = "kovidgoyal";
-          repo = "kitty";
-          rev = "refs/tags/v${version}";
-          hash = "sha256-VWWuC4T0pyTgqPNm0gNL1j3FShU5b8S157C1dKLon1g=";
-        };
+    src = prev.fetchFromGitHub {
+      owner = "kovidgoyal";
+      repo = "kitty";
+      rev = "refs/tags/v${version}";
+      hash = "sha256-VWWuC4T0pyTgqPNm0gNL1j3FShU5b8S157C1dKLon1g=";
+    };
 
-        goModules = (prev.buildGoModule {
-          pname = "kitty-go-modules";
-          inherit src version;
-          vendorHash = "sha256-OyZAWefSIiLQO0icxMIHWH3BKgNas8HIxLcse/qWKcU=";
-        }).goModules;
+    goModules = (prev.buildGoModule {
+      pname = "kitty-go-modules";
+      inherit src version;
+      vendorHash = "sha256-OyZAWefSIiLQO0icxMIHWH3BKgNas8HIxLcse/qWKcU=";
+    }).goModules;
 
-        patches = (oldAttrs.patches or [ ]) ++ [
-          ../patches/kitty-wlroots-copying-fix.patch
-        ];
-      });
-    })
-  ];
-}
+    patches = (oldAttrs.patches or [ ]) ++ [
+      ../patches/kitty-wlroots-copying-fix.patch
+    ];
+  });
+})

overlays/srb2.nix

@@ -1,20 +1,16 @@
-{
-  nixpkgs.overlays = [
-    (final: prev: {
-      srb2 = prev.srb2.overrideAttrs (oldAttrs: {
-        desktopItems = [
-          (prev.makeDesktopItem rec {
-            name = "Sonic Robo Blast 2";
-            exec = oldAttrs.pname;
-            icon = oldAttrs.pname;
-            comment = oldAttrs.meta.description;
-            desktopName = name;
-            genericName = name;
-            startupWMClass = ".srb2-wrapped";
-            categories = [ "Game" ];
-          })
-        ];
-      });
-    })
-  ];
-}
+(final: prev: {
+  srb2 = prev.srb2.overrideAttrs (oldAttrs: {
+    desktopItems = [
+      (prev.makeDesktopItem rec {
+        name = "Sonic Robo Blast 2";
+        exec = oldAttrs.pname;
+        icon = oldAttrs.pname;
+        comment = oldAttrs.meta.description;
+        desktopName = name;
+        genericName = name;
+        startupWMClass = ".srb2-wrapped";
+        categories = [ "Game" ];
+      })
+    ];
+  });
+})

overlays/zola.nix

@@ -1,9 +1,5 @@
-{
-  nixpkgs.overlays = [
-    (final: prev: {
-      zola = prev.zola.overrideAttrs (oldAttrs: {
-        patches = (oldAttrs.patches or [ ]) ++ [ ../patches/zola-serve-fix.patch ];
-      });
-    })
-  ];
-}
+(final: prev: {
+  zola = prev.zola.overrideAttrs (oldAttrs: {
+    patches = (oldAttrs.patches or [ ]) ++ [ ../patches/zola-serve-fix.patch ];
+  });
+})