From ef1de44b18c88849fc079b15ef481c45b87648b8 Mon Sep 17 00:00:00 2001
From: Donovan Glover <donovan@dglover.co>
Date: Wed, 4 Sep 2024 19:09:32 -0400
Subject: [PATCH] packages: Add desktop-icons

Has some bugs and lacks certain features like sorting but seems to work.
---
 packages/desktop-icons.nix | 51 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 packages/desktop-icons.nix

diff --git a/packages/desktop-icons.nix b/packages/desktop-icons.nix
new file mode 100644
index 00000000..e6e485c3
--- /dev/null
+++ b/packages/desktop-icons.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  gtk3,
+  gtk-layer-shell,
+  glib,
+  wrapGAppsHook3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "desktop-icons";
+  version = "0-unstable-2024-02-25";
+
+  src = fetchFromGitHub {
+    owner = "Geronymos";
+    repo = "desktop-icons";
+    rev = "5a1f4e12fcf405df7daf0986eb580efaad37c3c2";
+    hash = "sha256-Hp+eMai0KhFsD8rgs5TaEVSNviF9MhyNfKttzekAgQg=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    gtk3
+    gtk-layer-shell
+  ];
+
+  env.NIX_CFLAGS_COMPILE = "-I${glib.dev}/include/gio-unix-2.0";
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 dicons $out/bin/dicons
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Show files from a directory on the desktop for wlroots based compositors";
+    homepage = "https://github.com/Geronymos/desktop-icons";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ donovanglover ];
+    mainProgram = "dicons";
+    platforms = lib.platforms.all;
+  };
+})