Fix dirs removal warning (#14029)

# Description

* Primary purpose is to fix an issue with a missing escaped opening
parenthesis in the warning message when running an old `dirs` alias.
This was creating an error condition from improper interpolation.

Also

* Incorporates #13842 feedback from @kubouch by renaming `std/lib` to
`std/util`
* Removes duplication of code in `export-env`
* Renames submodule exports to `std/<submodule>` rather than
`./<submodule>` - No user-facing change other than `view files` appears
"prettier".
* In #13842, I converted the test cases to use `use std/<module>`
syntax. Previously, the tests were (effectively) using `use std *` (due
to pre-existing bugs, now fixed).

So "before", we only had test coverage on `use std *`, and "after" we
only had test coverage on `use std/<module>`. I've started adding test
cases so that we have coverage on *both* scenarios going forward.

For now, `formats` and `util` have been updated with tests for both
scenarios. I'll continue adding the others in future PRs.

# User-Facing Changes

No user-facing changes - Bug fix, refactor, and test cases only

# Tests + Formatting

- 🟢 `toolkit fmt`
- 🟢 `toolkit clippy`
- 🟢 `toolkit test`
- 🟢 `toolkit test stdlib`

# After Submitting

Still working on updating the Doc. I ran into the `dirs` issue while
writing it and rabbit-trailed to fix it in this PR.

crates/nu-std/tests/test_util.nu

@@ -0,0 +1,83 @@
+use std/util *
+
+#[test]
+def path_add [] {
+    use std/assert
+
+    let path_name = if "PATH" in $env { "PATH" } else { "Path" }
+
+    with-env {$path_name: []} {
+        def get_path [] { $env | get $path_name }
+
+        assert equal (get_path) []
+
+        path add "/foo/"
+        assert equal (get_path) (["/foo/"] | path expand)
+
+        path add "/bar/" "/baz/"
+        assert equal (get_path) (["/bar/", "/baz/", "/foo/"] | path expand)
+
+        load-env {$path_name: []}
+
+        path add "foo"
+        path add "bar" "baz" --append
+        assert equal (get_path) (["foo", "bar", "baz"] | path expand)
+
+        assert equal (path add "fooooo" --ret) (["fooooo", "foo", "bar", "baz"] | path expand)
+        assert equal (get_path) (["fooooo", "foo", "bar", "baz"] | path expand)
+
+        load-env {$path_name: []}
+
+        let target_paths = {
+            linux: "foo",
+            windows: "bar",
+            macos: "baz",
+            android: "quux",
+        }
+
+        path add $target_paths
+        assert equal (get_path) ([($target_paths | get $nu.os-info.name)] | path expand)
+
+        load-env {$path_name: [$"(["/foo", "/bar"] | path expand | str join (char esep))"]}
+        path add "~/foo"
+        assert equal (get_path) (["~/foo", "/foo", "/bar"] | path expand)
+    }
+}
+
+#[test]
+def path_add_expand [] {
+    use std/assert
+
+    # random paths to avoid collision, especially if left dangling on failure
+    let real_dir = $nu.temp-path | path join $"real-dir-(random chars)"
+    let link_dir = $nu.temp-path | path join $"link-dir-(random chars)"
+    mkdir $real_dir
+    let path_name = if $nu.os-info.family == 'windows' {
+        mklink /D $link_dir $real_dir
+        "Path"
+    } else {
+        ln -s $real_dir $link_dir | ignore
+        "PATH"
+    }
+
+    with-env {$path_name: []} {
+        def get_path [] { $env | get $path_name }
+
+        path add $link_dir
+        assert equal (get_path) ([$link_dir])
+    }
+
+    rm $real_dir $link_dir
+}
+
+#[test]
+def repeat_things [] {
+    use std/assert
+    assert error { "foo" | repeat -1 }
+
+    for x in ["foo", [1 2], {a: 1}] {
+        assert equal ($x | repeat 0) []
+        assert equal ($x | repeat 1) [$x]
+        assert equal ($x | repeat 2) [$x $x]
+    }
+}