mirror of
https://github.com/nushell/nushell.git
synced 2025-04-22 04:08:20 +02:00
ebabca575c
# Description Small, backwards compatible enhancements to the standard library. # User-Facing Changes - changed `iter find`, `iter find-index`: Only consume the input stream up to the first match. - added `log set-level`: a small convenience command for setting the log level - added `$null_device`: `null-device` as a const variable, would allow conditional sourcing if #13872 is fixed # Tests + Formatting - 🟢 toolkit fmt - 🟢 toolkit clippy - 🟢 toolkit test - 🟢 toolkit test stdlib # After Submitting N/A
67 lines
2.3 KiB
Plaintext
67 lines
2.3 KiB
Plaintext
# run a piece of `nushell` code multiple times and measure the time of execution.
|
|
#
|
|
# this command returns a benchmark report of the following form:
|
|
# ```
|
|
# record<
|
|
# mean: duration
|
|
# std: duration
|
|
# times: list<duration>
|
|
# >
|
|
# ```
|
|
#
|
|
# > **Note**
|
|
# > `std bench --pretty` will return a `string`.
|
|
#
|
|
# # Examples
|
|
# measure the performance of simple addition
|
|
# > std bench { 1 + 2 } -n 10 | table -e
|
|
# ╭───────┬────────────────────╮
|
|
# │ mean │ 4µs 956ns │
|
|
# │ std │ 4µs 831ns │
|
|
# │ │ ╭───┬────────────╮ │
|
|
# │ times │ │ 0 │ 19µs 402ns │ │
|
|
# │ │ │ 1 │ 4µs 322ns │ │
|
|
# │ │ │ 2 │ 3µs 352ns │ │
|
|
# │ │ │ 3 │ 2µs 966ns │ │
|
|
# │ │ │ 4 │ 3µs │ │
|
|
# │ │ │ 5 │ 3µs 86ns │ │
|
|
# │ │ │ 6 │ 3µs 84ns │ │
|
|
# │ │ │ 7 │ 3µs 604ns │ │
|
|
# │ │ │ 8 │ 3µs 98ns │ │
|
|
# │ │ │ 9 │ 3µs 653ns │ │
|
|
# │ │ ╰───┴────────────╯ │
|
|
# ╰───────┴────────────────────╯
|
|
#
|
|
# get a pretty benchmark report
|
|
# > std bench { 1 + 2 } --pretty
|
|
# 3µs 125ns +/- 2µs 408ns
|
|
export def main [
|
|
code: closure # the piece of `nushell` code to measure the performance of
|
|
--rounds (-n): int = 50 # the number of benchmark rounds (hopefully the more rounds the less variance)
|
|
--verbose (-v) # be more verbose (namely prints the progress)
|
|
--pretty # shows the results in human-readable format: "<mean> +/- <stddev>"
|
|
] {
|
|
let times: list<duration> = (
|
|
seq 1 $rounds | each {|i|
|
|
if $verbose { print -n $"($i) / ($rounds)\r" }
|
|
timeit { do $code }
|
|
}
|
|
)
|
|
|
|
if $verbose { print $"($rounds) / ($rounds)" }
|
|
|
|
let report = {
|
|
mean: ($times | math avg)
|
|
min: ($times | math min)
|
|
max: ($times | math max)
|
|
std: ($times | into int | math stddev | into int | into duration)
|
|
times: ($times)
|
|
}
|
|
|
|
if $pretty {
|
|
$"($report.mean) +/- ($report.std)"
|
|
} else {
|
|
$report
|
|
}
|
|
}
|