mirror of
https://github.com/nushell/nushell.git
synced 2025-04-22 12:18:20 +02:00
f33a26123c
`path add`, when given a record, sets `$env.PATH` according to the value of the key matching `$nu.os-info.name`. There already existed a check in place to ensure the correct column existed, but it was never reached because of an early error on `path expand`ing `null`. This has been fixed, as well as the out-of-date reference to "darwin" instead of "macos" in the example. # User-Facing Changes `path add` now simply ignores a record that doesn't include a key for the current OS `path add` also will no longer add duplicate paths.
91 lines
2.3 KiB
Plaintext
91 lines
2.3 KiB
Plaintext
use std/testing *
|
|
use std/util *
|
|
|
|
@test
|
|
def path_add [] {
|
|
use std/assert
|
|
|
|
let path_name = if "PATH" in $env { "PATH" } else { "Path" }
|
|
|
|
with-env {$path_name: []} {
|
|
def get_path [] { $env | get $path_name }
|
|
|
|
assert equal (get_path) []
|
|
|
|
path add "/foo/"
|
|
assert equal (get_path) (["/foo/"] | path expand)
|
|
|
|
path add "/bar/" "/baz/"
|
|
assert equal (get_path) (["/bar/", "/baz/", "/foo/"] | path expand)
|
|
|
|
load-env {$path_name: []}
|
|
|
|
path add "foo"
|
|
path add "bar" "baz" --append
|
|
assert equal (get_path) (["foo", "bar", "baz"] | path expand)
|
|
|
|
assert equal (path add "fooooo" --ret) (["fooooo", "foo", "bar", "baz"] | path expand)
|
|
assert equal (get_path) (["fooooo", "foo", "bar", "baz"] | path expand)
|
|
|
|
load-env {$path_name: []}
|
|
|
|
let target_paths = {
|
|
linux: "foo",
|
|
windows: "bar",
|
|
macos: "baz",
|
|
android: "quux",
|
|
}
|
|
|
|
path add $target_paths
|
|
assert equal (get_path) ([($target_paths | get $nu.os-info.name)] | path expand)
|
|
|
|
load-env {$path_name: []}
|
|
path add {}
|
|
assert equal (get_path) ([])
|
|
|
|
assert error {|| path add 1 }
|
|
|
|
load-env {$path_name: [$"(["/foo", "/bar"] | path expand | str join (char esep))"]}
|
|
path add "~/foo"
|
|
assert equal (get_path) (["~/foo", "/foo", "/bar"] | path expand)
|
|
}
|
|
}
|
|
|
|
@test
|
|
def path_add_expand [] {
|
|
use std/assert
|
|
|
|
# random paths to avoid collision, especially if left dangling on failure
|
|
let real_dir = $nu.temp-path | path join $"real-dir-(random chars)"
|
|
let link_dir = $nu.temp-path | path join $"link-dir-(random chars)"
|
|
mkdir $real_dir
|
|
let path_name = if $nu.os-info.family == 'windows' {
|
|
mklink /D $link_dir $real_dir
|
|
"Path"
|
|
} else {
|
|
ln -s $real_dir $link_dir | ignore
|
|
"PATH"
|
|
}
|
|
|
|
with-env {$path_name: []} {
|
|
def get_path [] { $env | get $path_name }
|
|
|
|
path add $link_dir
|
|
assert equal (get_path) ([$link_dir])
|
|
}
|
|
|
|
rm $real_dir $link_dir
|
|
}
|
|
|
|
@test
|
|
def repeat_things [] {
|
|
use std/assert
|
|
assert error { "foo" | repeat -1 }
|
|
|
|
for x in ["foo", [1 2], {a: 1}] {
|
|
assert equal ($x | repeat 0) []
|
|
assert equal ($x | repeat 1) [$x]
|
|
assert equal ($x | repeat 2) [$x $x]
|
|
}
|
|
}
|